&НаКлиенте
Функция ПолучитьДанныеОбАбонентеНаКлиенте(Знач НомерТелефона)
   Номера = Новый Массив(1);
   Номера[0] =  УбратьИзНомераСпецСимволы(НомерТелефона);
   врПараметры = Новый Структура;
   врПараметры.Вставить("КодСтраны", ПерсональныеНастройки.КодСтраны);
   врПараметры.Вставить("КодГорода", ПерсональныеНастройки.КодГорода);
   врПараметры.Вставить("АдресТЗКодыГородов", АдресТЗКодыГородов);
   // Проверим наличие данных в кэше
   ДанныеКэша = КэшКонтактнойИнформации.НайтиСтроки(Новый Структура("НомерТелефона", НомерТелефона));
   Если ДанныеКэша.Количество() > 0 Тогда
      Результат = Новый Структура("Абонент,
                     |Партнер,
                     |Город,
                     |Область,
                     |Страна,
                     |НомерТелефона");
      ЗаполнитьЗначенияСвойств(Результат, ДанныеКэша[0]); 
      Возврат Результат;
   КонецЕсли;
   
   Результат = ПолучитьДанныеОбАбонентеБезКонтекста(Номера, ТекстЗапросКИ2, врПараметры);
   // Сохраним данные в кэше
   Если ЗначениеЗаполнено(Результат.НомерТелефона) Тогда
      СтрокаКэша = КэшКонтактнойИнформации.Добавить();
      ЗаполнитьЗначенияСвойств(СтрокаКэша, Результат);
      СтрокаКэша.НомерТелефона = Номера[0];
   Иначе   
       Результат.НомерТелефона = Номера[0]; 
   КонецЕсли; 
   // Почистим кэш
   Если КэшКонтактнойИнформации.Количество() > 128 Тогда
      КэшКонтактнойИнформации.Удалить(0);
   КонецЕсли;

   Возврат Результат;
КонецФункции // ПолучитьДанныеОбАбонентеНаКлиенте()

&НаСервереБезКонтекста 
Функция ПолучитьДанныеОбАбонентеБезКонтекста(Знач Номера, Знач ТекстЗапроса, Знач Параметры) Экспорт
   
   Результат = Новый Структура("Абонент,
                        |Партнер,
                        |Город,
                        |Область,
                        |Страна,
                        |НомерТелефона");                     
   Запрос = Новый Запрос(ТекстЗапроса);
   
   Запрос.УстановитьПараметр("Номера", Номера);
   Запрос.УстановитьПараметр("КодСтраны", Параметры.КодСтраны);
   Запрос.УстановитьПараметр("КодГорода", Параметры.КодГорода);
   
   // Найдем информацию о номере по базе кодов городов
   Запрос.Текст = Запрос.Текст + ";ВЫБРАТЬ
                                 |   ТабКодыГородов.ШаблонПоиска КАК ШаблонПоиска,
                                 |   ТабКодыГородов.КодСтраны,
                                 |   ТабКодыГородов.КодГорода,
                                 |   ТабКодыГородов.Город,
                                 |   ТабКодыГородов.Область,
                                 |   ТабКодыГородов.Страна
                                 |ПОМЕСТИТЬ втКодыГородов
                                 |ИЗ
                                 |   &ТабКодыГородов КАК ТабКодыГородов
                                 |
                                 |ИНДЕКСИРОВАТЬ ПО
                                 |   ШаблонПоиска
                                 |;
                                 |
                                 |////////////////////////////////////////////////////////////////////////////////
                                 |ВЫБРАТЬ ПЕРВЫЕ 1
                                 |   КодыГородов.ШаблонПоиска,
                                 |   КодыГородов.Город,
                                 |   КодыГородов.Область,
                                 |   КодыГородов.Страна,
                                 |   КодыГородов.КодГорода,
                                 |   КодыГородов.КодСтраны
                                 |ИЗ
                                 |   втКодыГородов КАК КодыГородов
                                 |ГДЕ
                                 |   &НомерДляПоискаГорода ПОДОБНО КодыГородов.ШаблонПоиска
                                 |
                                 |УПОРЯДОЧИТЬ ПО
                                 |   КодыГородов.ШаблонПоиска УБЫВ";
   НомерДляПоискаГорода = Номера[0];                       
   Если Лев(НомерДляПоискаГорода, 1) = "8" И СтрДлина(НомерДляПоискаГорода) = 11 Тогда
       НомерДляПоискаГорода = "7" + Прав(НомерДляПоискаГорода, СтрДлина(НомерДляПоискаГорода) - 1);
   КонецЕсли; 
   
   Запрос.УстановитьПараметр("КороткийНомер", ?(СтрДлина(Номера[0])>6,Прав(Номера[0],9),""));
   Запрос.УстановитьПараметр("ТабКодыГородов", ПолучитьИзВременногоХранилища(Параметры.АдресТЗКодыГородов));
   Запрос.УстановитьПараметр("НомерДляПоискаГорода", НомерДляПоискаГорода);
   РезультатЗапроса = Запрос.ВыполнитьПакет();
   
   Если Не РезультатЗапроса[1].Пустой() Тогда
      Выборка = РезультатЗапроса[1].Выбрать();
      Если Выборка.Следующий() Тогда
         ЗаполнитьЗначенияСвойств(Результат, Выборка);
      КонецЕсли; 
   КонецЕсли;
   Если Не РезультатЗапроса[3].Пустой() Тогда
      Выборка = РезультатЗапроса[3].Выбрать();
      Если Выборка.Следующий() Тогда
         ЗаполнитьЗначенияСвойств(Результат, Выборка);
         Страна = "";
         Если Найти(Врег(Выборка.Страна), "УКРАИНА")>0  Тогда
             Страна = "Украина";   
         ИначеЕсли Найти(Врег(Выборка.Страна), "РОСС")>0 Тогда   
             Страна = "Россия";   
         КонецЕсли; 
         Результат.Страна = Страна;
         НомерТелефона = Выборка.КодСтраны + "(" + Выборка.КодГорода + ")" 
                     + Сред(Номера[0], СтрДлина(Выборка.КодСтраны + Выборка.КодГорода) + 1);
         Результат.НомерТелефона = НомерТелефона;
      КонецЕсли; 
   КонецЕсли;
   
   Возврат Результат;
КонецФункции // ПолучитьДанныеОбАбоненте()